cmake_minimum_required(VERSION 3.16)

project(libkubuntu)

find_package(ECM 6.0.0 REQUIRED NO_MODULE)
set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})

include(ECMGenerateHeaders)
include(ECMPackageConfigHelpers)
include(ECMSetupVersion)
include(FeatureSummary)
include(KDEInstallDirs)
include(KDECMakeSettings)
include(KDECompilerSettings NO_POLICY_SCOPE)

include(CMakePackageConfigHelpers)

set(REQUIRED_QT_VERSION 6.5.0)
find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)

find_package(KF6 REQUIRED
    COMPONENTS
        Config
        I18n)

find_package(PackageKitQt6 REQUIRED)

ecm_setup_version(1.0.0 VARIABLE_PREFIX KUBUNTU
    SOVERSION 1
    PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KubuntuConfigVersion.cmake"
        COMPATIBILITY SameMajorVersion)

# --------------------------

add_subdirectory(autotests)
add_subdirectory(src)

# --------------------------

set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/Kubuntu")

ecm_configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/KubuntuConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/KubuntuConfig.cmake"
    INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR})

install(FILES "${CMAKE_CURRENT_BINARY_DIR}/KubuntuConfig.cmake"
              "${CMAKE_CURRENT_BINARY_DIR}/KubuntuConfigVersion.cmake"
        DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
        COMPONENT Devel)

install(EXPORT KubuntuTargets
    DESTINATION ${CMAKECONFIG_INSTALL_DIR}
    NAMESPACE Kubuntu::
    FILE KubuntuTargets.cmake)

feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
